VBScript's date formatting doesn't offer a huge number of options compared to PHP's date() function. While it's relatively easy to just write small snippets of code every time you need to format a date a specific way, life would be much easier if there was a function you could call on time and again to do the work for you.

Below, you will find three date format functions, all of which make some use of Unix timestamps, a concept most ASP developers will not be familiar with. Unix timestamps are defined as the number of seconds since the epoch, 00:00:00 01/01/1970, and are a very sensible way to store dates and times in a database, in my opinion. They are very easy to work with, especially when selecting data from a database, and once you are used to them, they can make life much much simpler.

NOTE: These functions were updated on the 15th March 2004 to fix a couple of known bugs. In addition, any scripts using these functions may need to be tweaked to take account of your locale. Each locale will use a slightly different date and time format, so please check yours before using these functions, or simply set your locale to UK. To set your locale to UK, you can use the code below:

1. <%@LANGUAGE=VBSCRIPT" LCID=2057%>

There is also a complete list of valid locales on the Microsoft website, with the values in the right hand column being the ones you will want.

Finally, the "monthname" function is VBScript is not present in every version, so may need to be defined manually. Please see comments on this article for an example.

The first function, UDate(), will convert a normal date into a Unix timestamp. The second function, unUDate(), simply does the reverse, converting any timestamp into a readable date. The last function takes a date and a format string, and returns a formatted date according to what you put into the formatting string.

UDate()

1. function UDate(oldDate)
2. UDate = DateDiff("s", "01/01/1970 00:00:00", oldDate)
3. end function

In practice, UDate is very easy to use. For example, if you want to know the current Unix time (the number of seconds since the epoch), you would use something like the following, which would give intCurrent_Unix_Time a value of 1069916571 at the time of writing.

1. intCurrent_Unix_Time = UDate(Now())

unUDate()

1. function unUDate(intTimeStamp)
2. unUDate = DateAdd("s", intTimeStamp, "01/01/1970 00:00:00")
3. end function

unUDate is as easy to use as UDate. Simply feed in an integer, and it will return a matching date. It will treat the integer as the number of seconds between the epoch and the desired date, and will return a properly formatted date for normal use in VBScript accordingly.

formatDate()

Now here's where it starts to get tricky. formatDate is also quite easy to use, but only once you get the hang of how it works. As you can see from the below, formatDate requires two values to be passed to it. The first, format, is a string telling the function how you would like the date formatted, and the second, intTimeStamp, can be either a Unix timestamp (preferred) or a normal VBScript date.

The format of the string is what we want to make use of to lay out our dates exactly as we would like, and perhaps this is best shown with an example. I would like a date displayed on my site in the following format: "7:11am, Thursday 27th November, 2003". In normal VBScript that would be a pain to format - I'd probably just end up giving up and using the normal VBLongTime and VBLongDate to display something similar. I would prefer complete control though...

The format string for formatDate can include a whole selection of characters to represent certain date or time entities. There's a table of the ones included in this function just below here. The format string needs to include these entities where it wants them to be replaced by the correct time or date value. To get the above formatted date and time, then, I could use the following:

1. strDateTime = formatDate("%g:%i%a, %l %j%O %F, %Y", UDate(Now()))

That looks a lot harder than it actually is. To tell the function we are aiming to replace a specific entity in the string with a time or date element, we use a symbol made up of a percent sign (%) and a letter. It is a case sensitive function, so be careful you form your format strings correctly. Without further ado, here's a list of the entities you can include in the format string (anything in the string that is not an entity from the list below will still be in the string when it has been processed).

• %A - AM or PM
• %a - am or pm
• %m - Month with leading zeroes (01 - 12)
• %n - Month without leading zeroes (1 - 12)
• %F - Month name (January - December)
• %M - Three letter month name (Jan - Dec)
• $d - Day with leading zeroes (01 - 31)
• %j - Day without leading zeroes (1 - 31)
• %H - Hour with leading zeroes (12 hour)
• %h - Hour with leading zeroes (24 hour)
• %G - Hour without leading zeroes (12 hour)
• %g - Hour without leading zeroes (24 hour)
• %i - Minute with leading zeroes (01 to 60)
• %I - Minute without leading zeroes (1 to 60)
• %s - Second with leading zeroes (01 to 60)
• %S - Second without leading zeroes (1 to 60)
• %L - Number of day of week (1 to 7)
• %l - Name of day of week (Sunday to Saturday)
• %D - Three letter name of day of week (Sun to Sat)
• %O - Ordinal suffix (st, nd rd, th)
• %U - UNIX Timestamp
• %Y - Four digit year (2003)
• %y - Two digit year (03)

You can include any of the above in the format string at any point. I would recommend not using a percentage sign if you can help it (except obviously as part of one of the elements above), and in the same vein, using ordinals anywhere except after a number is slightly foolish.

If you would like to see anything else added to the list, above, please email me and I will see what I can do.

The below is the formatDate function itself. To use, simply copy and paste it into a script or include file and call it as above, with whichever format string you require.

1. function formatDate(format, intTimeStamp)
2. dim unUDate, A
3.  
4. ' Test to see if intTimeStamp looks valid. If not, they have passed a normal date
5. if not (isnumeric(intTimeStamp)) then
6. if isdate(intTimeStamp) then
7. intTimeStamp = DateDiff("S", "01/01/1970 00:00:00", intTimeStamp)
8. else
9. response.write "Date Invalid"
10. exit function
11. end if
12. end if
14. if (intTimeStamp=0) then
15. unUDate = now()
16. else
17. unUDate = DateAdd("s", intTimeStamp, "01/01/1970 00:00:00")
18. end if
19.  
20. unUDate = trim(unUDate)
21.  
22. dim startM : startM = InStr(1, unUDate, "/", vbTextCompare) + 1
23. dim startY : startY = InStr(startM, unUDate, "/", vbTextCompare) + 1
24. dim startHour : startHour = InStr(startY, unUDate, " ", vbTextCompare) + 1
25. dim startMin : startMin = InStr(startHour, unUDate, ":", vbTextCompare) + 1
26.  
27. dim dateDay : dateDay = mid(unUDate, 1, 2)
28. dim dateMonth : dateMonth = mid(unUDate, startM, 2)
29. dim dateYear : dateYear = mid(unUDate, startY, 4)
30. dim dateHour : dateHour = mid(unUDate, startHour, 2)
31. dim dateMinute : dateMinute = mid(unUDate, startMin, 2)
32. dim dateSecond : dateSecond = mid(unUDate, InStr(startMin, unUDate, ":", vbTextCompare) + 1, 2)
33.  
34. format = replace(format, "%Y", right(dateYear, 4))
35. format = replace(format, "%y", right(dateYear, 2))
36. format = replace(format, "%m", dateMonth)
37. format = replace(format, "%n", cint(dateMonth))
38. format = replace(format, "%F", monthname(cint(dateMonth)))
39. format = replace(format, "%M", left(monthname(cint(dateMonth)), 3))
40. format = replace(format, "%d", dateDay)
41. format = replace(format, "%j", cint(dateDay))
42. format = replace(format, "%h", mid(unUDate, startHour, 2))
43. format = replace(format, "%g", cint(mid(unUDate, startHour, 2)))
44.  
45. if (cint(dateHour) > 12) then
46. A = "PM"
47. else
48. A = "AM"
49. end if
50. format = replace(format, "%A", A)
51. format = replace(format, "%a", lcase(A))
52.  
53. if (A = "PM") then format = replace(format, "%H", left("0" & dateHour - 12, 2))
54. format = replace(format, "%H", dateHour)
55. if (A = "PM") then format = replace(format, "%G", left("0" & cint(dateHour) - 12, 2))
56. format = replace(format, "%G", cint(dateHour))
57.  
58. format = replace(format, "%i", dateMinute)
59. format = replace(format, "%I", cint(dateMinute))
60. format = replace(format, "%s", dateSecond)
61. format = replace(format, "%S", cint(dateSecond))
62. format = replace(format, "%L", WeekDay(unUDate))
63. format = replace(format, "%D", left(WeekDayName(WeekDay(unUDate)), 3))
64. format = replace(format, "%l", WeekDayName(WeekDay(unUDate)))
65. format = replace(format, "%U", intTimeStamp)
66. format = replace(format, "11%O", "11th")
67. format = replace(format, "1%O", "1st")
68. format = replace(format, "12%O", "12th")
69. format = replace(format, "2%O", "2nd")
70. format = replace(format, "13%O", "13th")
71. format = replace(format, "3%O", "3rd")
72. format = replace(format, "%O", "th")
73.  
74. formatDate = format
75.  
76. end function